UCURE

User subroutine to define cure kinetics

User subroutine UCURE:

can be used to define cure kinetics for the cure modeling capabilities;
is called at all material points for elements for which the material definition includes user-defined cure kinetics;
can use and update solution-dependent state variables; and
requires that the degree of cure rate and its derivatives with respect to temperature and the degree of cure be defined.

This page discusses:

User Subroutine Interface
Variables to Be Defined
Variables That Can Be Updated
Variables Passed in for Information
Example: Kamal Model

User Subroutine Interface

SUBROUTINE UCURE(
     *   DOC, DOCRATEARRAY, NOEL ,NPT, LAYER, KSPT, KSTEP, KINC, JPROC,
     *   CMNAME, NSTATV, STATEVOLD, STATEV, COORDS, TIME, DTIME, PNEWDT,
     *   TEMP, DTEMP, NFIELD, PREDEF, DPRED, NPROPS, PROPS, 
     *   NIARRAY, I_ARRAY, NRARRAY, R_ARRAY, NCARRAY, C_ARRAY)
C
      INCLUDE 'ABA_PARAM.INC'
C
      DIMENSION
     *   DOCRATEARRAY(*),
     *   STATEVOLD(*),
     *   STATEV(*),
     *   COORDS(*),
     *   TIME(*),
     *   PREDEF(*),
     *   DPRED(*),
     *   PROPS(*),
     *   I_ARRAY(*),
     *   R_ARRAY(*)
C
      CHARACTER*80 C_ARRAY(*),CMNAME

      user coding to define DOCRATEARRAY, STATEV

      RETURN
      END

Variables to Be Defined

DOCRATEARRAY(1): Rate of degree of cure, $\dot{α}$ .
DOCRATEARRAY(2): Derivative of the rate of degree of cure with respect to degree of cure, $\frac{\partial \dot{α}}{\partial α}$ .
DOCRATEARRAY(3): Derivative of the rate of degree of cure with respect to temperature, $\frac{\partial \dot{α}}{\partial θ}$ .

Variables That Can Be Updated

STATEV: Array containing the user-defined solution-dependent state variables at this point. These are supplied as values at the start of the increment or as values updated by other user subroutines (see About User Subroutines and Utilities) and must be returned as values at the end of the increment.

Variables Passed in for Information

DOC

Degree of cure.

NOEL

Element number.

NPT

Integration point number.

LAYER

Layer number (for composite shells and layered solids).

KSPT

Section point number within the current layer.

KSTEP

Step number.

KINC

Increment number.

JPROC

Procedure type key.

CMNAME

User-specified material name, left justified.

NSTATV

User-defined number of solution-dependent state variables associated with this material (see Allocating Space for Solution-Dependent State Variables).

STATEVOLD

Array containing the user-defined solution-dependent state variables at the beginning of the increment.

COORDS

Array containing the current coordinates at this point.

TIME(1)

Value of step time at the end of the increment.

TIME(2)

Value of total time at the end of the increment

TIME(3)

Value of creep time at the end of the increment.

DTIME

Time increment.

PNEWDT

Ratio of suggested new time increment to the time increment being used (DTIME). This variable allows you to provide input to the automatic time incrementation algorithms in Abaqus/Standard if automatic time incrementation is chosen.

PNEWDT is set to a large value before each call to UCURE.

If PNEWDT is redefined to be less than 1.0, Abaqus/Standard must abandon the time increment and attempt it again with a smaller time increment. The suggested new time increment provided to the automatic time integration algorithms is PNEWDT × DTIME, where PNEWDT is the minimum value for all calls to user subroutines that allow redefinition of PNEWDT for this iteration.

If PNEWDT is given a value that is greater than 1.0 for all calls to user subroutines for this iteration and the increment converges in this iteration, Abaqus/Standard might increase the time increment. The suggested new time increment provided to the automatic time integration algorithms is PNEWDT × DTIME, where PNEWDT is the minimum value for all calls to user subroutines for this iteration.

If automatic time incrementation is not selected in the analysis procedure, values of PNEWDT that are greater than 1.0 will be ignored and values of PNEWDT that are less than 1.0 will cause the job to end.

TEMP

Temperature at the end of the increment.

DTEMP

Increment of temperature.

NFIELD

Number of field variables.

PREDEF

Array of interpolated values of predefined field variables at this material point at the end of the increment based on the values read in at the nodes (initial values at the beginning of the analysis and current values during the analysis).

DPRED

Array of increments of predefined field variables at this material point for this increment, including any values updated by user subroutine USDFLD.

NPROPS

Number of material properties entered for this user-defined cure kinetics model.

PROPS

Array of material properties entered for this user-defined cure kinetics model.

NIARRAY

Not used.

I_ARRAY

Not used.

NRARRAY

Not used.

R_ARRAY

Not used.

NCARRAY

Not used.

C_ARRAY

Not used.

Example: Kamal Model

As an example of the coding of user subroutine UCURE, consider a special case of the Kamal model with one term and $m_{1} = 0$ , $n_{1} = 1.0$ , $b_{1} = 0$ , and $α_{\max} = 1.0$ . In this case the Kamal equation has the form

\dot{α} = Z_{1} e^{- \frac{E_{1}}{R (θ - θ^{Z})}} (1 - α),

where

α

denotes the degree of cure,

Z_{1}

is a parameter,

E_{1}

is the activation energy,

R

is the universal gas constant, and

θ^{Z}

is the absolute zero temperature. The derivatives of the degree of cure rate with respect to temperature and with respect to degree of cure are given by the following relations:

\frac{\partial \dot{α}}{\partial θ} = \frac{E_{1} \dot{α}}{R {(θ - θ^{Z})}^{2}}

and

\frac{\partial \dot{α}}{\partial α} = - Z_{1} e^{- \frac{E_{1}}{R (θ - θ^{Z})}} .

The user subroutine is coded as follows:

      SUBROUTINE UCURE(
     *   DOC, DOCRATEARRAY, NOEL, NPT, LAYER, KSPT, KSTEP, KINC, JPROC,
     *   CMNAME, NSTATV, STATEVOLD, STATEV,
     *   COORDS, TIME, DTIME, PNEWDT, TEMP, DTEMP, NFIELD, PREDEF,
     *   DPRED, NPROPS, PROPS, NIARRAY, I_ARRAY, NRARRAY, R_ARRAY, NCARRAY, C_ARRAY )
C
      INCLUDE 'ABA_PARAM.INC'
      INCLUDE 'ABA_PHCON_PARAM.INC'
C
      PARAMETER (SMALL=1.D-6, ZERO=0.0D0, HALF=0.5D0, ONE=1.0D0)
      DIMENSION 
     *   DOCRATEARRAY(*),
     *   STATEVOLD(*),
     *   STATEV(*),
     *   COORDS(*),
     *   TIME(*),
     *   PREDEF(*),
     *   DPRED(*),
     *   PROPS(*),
     *   I_ARRAY(*),
     *   R_ARRAY(*)
C
      CHARACTER*80 C_ARRAY(*),CMNAME
C
c   Initialize variables
c
      jError = 0
      R = zero
      tempZero = zero
      alphaDot = zero
      dAlphaDotDT = zero
      dAlphaDotdAlpha = zero
C
C ... Read absolute zero temperature and universal gas constant
C
      call getphysicalconstant(j_phcon_Abs0, tempZero, jError)
      if (jError.ne.0) tempZero = zero
      call getphysicalconstant(j_phcon_UnivGas, R, jError)
      if (jError.ne.0) R = one
C
C ... Read material properties
C
      Zi = props(1)
      Ei = props(2)
      Ei = Ei/R
C
      tempDiff = max(zero,temp-tempZero)
      test = half - sign(half,tempDiff-small)
C
C ... Compute the degree of cure rate and its derivatives
C
      arrhenius = (one-test)*Zi*exp(-Ei/(test + tempDiff))
      alphaDot = arrhenius*(one-doc)
      dAlphaDotDT = alphaDot*Ei/(test + tempDiff)**2
      dAlphaDotdAlpha = -arrhenius
C
      DOCRATEARRAY(1) = alphaDot
      DOCRATEARRAY(2) = dAlphaDotdAlpha
      DOCRATEARRAY(3) = dAlphaDotDT
c
      RETURN
      END